home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
System Booster
/
System Booster.iso
/
Commodities
/
Event!
/
Install Event!
< prev
next >
Wrap
Text File
|
1996-09-26
|
8KB
|
399 lines
; Install script for Event!)
;*********
; Strings
;*********
(set #bad-kick
(cat "You must be using Kickstart 2.04 or higher to install using this script!"
))
(set #which-language
(cat "\nWhich languages should be installed?\n"
"(English is automatically available)"
))
(set #which-language-help
(cat "\nThe Amiga can be operated in many different"
" languages. If you want Event! to use the same"
" language as the Amiga Workbench"
" then a catalog file must be copied to your"
" harddisk for each language supported.\n\n"
"To reduce the amount of space consumed by the"
" language files, you can select to have only the"
" files of specific languages copied.\n\n"
"Simply check the boxes of the languages you wish"
" to have available on your system.\n\n"
@askoptions-help
))
(set #tocopy
(cat "Files to copy:"
))
(set #copy-main "\n\n\n\n\nInstall the Event Scheduler?")
(set #copy-main-help
(cat "\nThis will install the Event! main program."
))
(set #copy-keyfile "\n\n\n\n\nInstall the keyfile for Event! ?\n(strongly advised ;) )")
(set #copy-keyfile-help
(cat "\nThis will install Event!'s keyfile,\n"
"which will disable the shareware\n"
"reminder at program startup."
))
(set #copy-cfg "\n\n\n\n\nInstall the default configuration?")
(set #copy-cfg-help
(cat "\nThis will install the default configuration."
))
(set #copy-tell "\n\n\n\n\nInstall the TellEvent! command?")
(set #copy-tell-help
(cat "\nThis will install the TellEvent! command.\n"
"TellEvent! can be used to send messages to the\n"
"ARexx-Port of Event!"
))
(set #copy-arexx "\nInstall supplied ARexx scripts?")
(set #copy-arexx-help
(cat "\nThis will install some example ARexx scripts "
"that are included in the Event! distribution."
))
(set #copy-arexx-spot "\nInstall ARexx scripts supporting Spot?")
(set #copy-arexx-spot-help
(cat "\nThis will install some example ARexx scripts\n"
"that are included in the Event! distribution for\n"
"use with Spot."
))
(set #copy-arexx-ced "\nInstall ARexx scripts supporting CygnusED?")
(set #copy-arexx-ced-help
(cat "\nThis will install an example ARexx script"
"that is included in the Event! distribution for use with CygnusED."
))
(set #install-msg
(cat "Installation program for\n"
" ________________________________________________\n"
" (_______________________________________ ______/\n"
" _____ ___ ____ _____ __ __ / / __ \n"
" / ____)| | / / / ____) / | / / / / / / \n"
" / /__ | | / / / /__ / ( / / / / / / \n"
" / ___/ | |/ / / ___/ / /| ) / / / (_/ \n"
" / /__ | / / / /__ / / | |/ / / _ \n"
" (_____) (/_/ (_____) (_/ |_/ /_/ (_) \n"
" _______________________________________________ \n"
"(______________________________________________/ \n\n"
"The Event Scheduler for the Commodore Amiga\n"
"©1992-94 by Stefan Hochmuth. All rights reserved."
))
;*******************************************
; make sure Kick 2.0 or higher is available
;*******************************************
(if (< (/ (getversion) 65536) 37)
(
(abort #bad-kick)
))
(message #install-msg)
(welcome)
(set addtouserstartup 0)
(set addtowbstartup 0)
;*****************
; Install Program
;*****************
(if
(askbool
(prompt #copy-main)
(help #copy-main-help)
(default 1)
)
(
(set eventdest
(askdir
(prompt "Please select a drawer for Event!:\n"
"If the drawer is different from\n"
"\"SYS:WBStartup\" Event! can optionally\n"
"be added to \"s:user-startup\"."
)
(help @askdir-help)
(default "SYS:WBStartup")
(newpath)
)
)
(copyfiles
(prompt "Installing Event!...")
(source "Event!")
(infos)
(noposition)
(help @copylib-help)
(dest eventdest)
)
(if (= eventdest "SYS:WBStartup")
; set tooltype
; ------------
(
(tooltype
(dest (tackon eventdest "Event!"))
(settooltype "CX_POPUP" "NO")
)
(set addtowbstartup 1)
)
; add to user-startup
; -------------------
(
(set addtouserstartup 1)
)
)
)
)
; *****************************************
; Install the Keyfile for registered users
; *****************************************
(if (exists "event!.key")
(if
(askbool
(prompt #copy-keyfile)
(help #copy-keyfile-help)
(default 1)
)
(copyfiles
(help @copy-keyfile-help)
(prompt #tocopy)
(source "Event!.key")
(dest "devs:")
)
)
)
; ******************************
; Install Default Configuration
; ******************************
(if (NOT (exists "s:event!.cfg"))
(if
(askbool
(prompt #copy-cfg)
(help #copy-cfg-help)
(default 1)
)
(
(set cfgdest (cat "s:"))
(copyfiles
(help @copyfiles-help)
(prompt #tocopy)
(source "Event!.cfg")
(dest cfgdest)
(confirm)
)
)
)
)
;******************************
; Install TellEvent! - command
;******************************
(if
(askbool
(prompt #copy-tell)
(help #copy-tell-help)
(default 1)
)
(
(set telldest
(askdir
(prompt "Please select a drawer for TellEvent!.")
(help @askdir-help)
(default "C:")
(newpath)
)
)
(copyfiles
(prompt "Installing TellEvent!...")
(source "Util/TellEvent!")
(help @copylib-help)
(dest telldest)
)
)
)
;***********************
; Install ARexx-Scripts
;***********************
(if
(askbool
(prompt #copy-arexx)
(help #copy-arexx-help)
(default 1)
)
(
(set rexxdest (cat "REXX:"))
(copyfiles
(help @copyfiles-help)
(prompt #tocopy)
(source "Rexx")
(dest RexxDest)
(pattern "#?.evt")
(confirm)
)
)
)
;*****************************************
; Install ARexx-Scripts for use with Spot
;*****************************************
(if
(askbool
(prompt #copy-arexx-spot)
(help #copy-arexx-spot-help)
(default 1)
)
(
(set rexxspotdest (cat "REXX:spot"))
(copyfiles
(help @copyfiles-help)
(prompt #tocopy)
(source "Rexx")
(dest rexxspotdest)
(pattern "#?.spot")
(confirm)
)
)
)
;*****************************************
; Install ARexx-Scripts for use with CED
;*****************************************
(if
(askbool
(prompt #copy-arexx-ced)
(help #copy-arexx-ced-help)
(default 1)
)
(
(set rexxceddest (cat "REXX:"))
(copyfiles
(help @copyfiles-help)
(source "Rexx")
(dest rexxceddest)
(pattern "#?.ced")
(prompt #tocopy)
(confirm)
)
)
)
;*******************
; Install Languages
;*******************
(if (exists "libs:locale.library")
(copyfiles
(help @copyfiles-help)
(source "Catalogs")
(dest "Locale:Catalogs")
(all)
(prompt #which-language)
(confirm average)
)
)
;***********************
; Install Documentation
;***********************
(set guidedest
(askdir
(prompt "Please select a drawer for Event!'s\n"
"AmigaGuide documentation:")
(help @askdir-help)
(default "SYS:Utilities/guides")
(newpath)
)
)
(copyfiles
(prompt "Installing Documentation...")
(source "Docs/Event!.guide")
(infos)
(noposition)
(help @copylib-help)
(dest guidedest)
)
(if addtowbstartup
(tooltype
(dest (tackon eventdest "Event!"))
(settooltype "GUIDE" (tackon guidedest "Event!.guide") )
)
)
(if addtouserstartup
(
(set oldlevel @user-level)
(if (> oldlevel 0)
(user 2)
)
(startup "Event!"
(command "run >NIL: \""
(tackon eventdest "Event!")
"\" CX_POPUP=NO GUIDE=\""
(tackon guidedest "Event!.guide\"")
)
(prompt (cat "\n\n\n\nReady to add \""
(tackon eventdest "Event!")
"\" to s:user-startup?"
)
)
(help @startup-help)
)
(user oldlevel)
)
)
(if (>= (/ (getversion) 65536) 39)
(tooltype
(dest (tackon guidedest "Event!.guide"))
(setdefaulttool "SYS:Utilities/MultiView")
)
(tooltype
(dest (tackon guidedest "Event!.guide"))
(setdefaulttool "SYS:Utilities/AmigaGuide")
)
)
(set @default-dest eventdest)